Passa ai contenuti principali

Come ti estendo lo startup di un’applicazione web

In questo post vorrei porre l’attenzione su una modalità (a dir la verità abbastanza misconosciuta) per estendere lo startup di una applicazione web.

Con il termine “estendere lo startup” di una applicazione web intendo la possibilità di eseguire del codice (vedremo in seguito sotto quali condizioni) senza dover ricorrere alla modifica del Global.asax o alla modifica del file di configurazione (ad esempio per aggiungere dei Module).

La “magica” classe che permette tutto ciò è la PreApplicationStartMethodAttribute contenuta nel namespace System.Web (assembly System.Web.dll).

Si tratta di un attributo applicabile ad un assembly che permette di dichiarare un metodo di un tipo che deve essere eseguito allo startup dell’applicazione.

Cosa vuol dire in soldoni?

Facciamo un esempio molto semplice ma che può far capire il meccanismo.

Supponiamo di voler creare un Modulo HTTP che venga automaticamente agganciato al nostro sito web e che si occupi di non permettere di scaricare risorse da una determinata cartella (ad esempio una cartella chiamata “protected”).

Il nostro module ha una forma del genere:

  1. Imports System.Web
  2.  
  3. Public Class ProtectionModule
  4.     Implements IHttpModule
  5.  
  6.     Public Sub Dispose() Implements System.Web.IHttpModule.Dispose
  7.  
  8.     End Sub
  9.  
  10.     Public Sub Init(context As System.Web.HttpApplication) Implements System.Web.IHttpModule.Init
  11.         AddHandler context.EndRequest, AddressOf EndRequestHandler
  12.     End Sub
  13.  
  14.     Private Sub EndRequestHandler(sender As Object, e As EventArgs)
  15.         Dim app = CType(sender, HttpApplication)
  16.         If app.Request.FilePath.ToLower().StartsWith("/protected") Then
  17.             app.Response.ClearContent()
  18.         End If
  19.     End Sub
  20. End Class

Semplicemente, all’interno del gestore di evento EndRequest, verifichiamo che la risorsa non sia contenuta nella cartella “Protected” (o in una sua sottocartella) e, in quel caso, svuotiamo il contenuto della response.

A questo punto il modulo deve essere agganciato al nostro sito utilizzando l’apposita sezione di configurazione del web.config, ma noi vogliamo fare in modo che tale modulo sia agganciato sempre a prescindere dalla configurazione.

Per fare questo definiamo un metodo shared che verrà richiamato dal framework alla partenza dell’applicazione (Start):

  1. Public Sub Start()
  2.      DynamicModuleUtility.RegisterModule(GetType(ProtectionModule))
  3. End Sub

La classe DynamicModuleUtility si trova nel namespace Microsoft.Web.Infrastructure.DynamicModuleHelper e permette di registrare a run-time un modulo.

Definito il modulo e creato il metodo di start non ci resta che utilizzare l’attributo PreApplicationStartMethodAttribute per dire al framework di eseguire lo Start all’avvio dell’applicazione:

  1. Imports System.Web
  2. Imports Microsoft.Web.Infrastructure.DynamicModuleHelper
  3.  
  4. <Assembly: PreApplicationStartMethod(GetType(protectionModule), "Start")>
  5.  
  6. Public Class ProtectionModule
  7.     Implements IHttpModule
  8.  
  9.     Public Shared Sub Start()
  10.         DynamicModuleUtility.RegisterModule(GetType(ProtectionModule))
  11.     End Sub
  12.  
  13.     Public Sub Dispose() Implements System.Web.IHttpModule.Dispose
  14.  
  15.     End Sub
  16.  
  17.     Public Sub Init(context As System.Web.HttpApplication) Implements System.Web.IHttpModule.Init
  18.         AddHandler context.EndRequest, AddressOf EndRequestHandler
  19.     End Sub
  20.  
  21.     Private Sub EndRequestHandler(sender As Object, e As EventArgs)
  22.         Dim app = CType(sender, HttpApplication)
  23.         If app.Request.FilePath.ToLower().StartsWith("/protected") Then
  24.             app.Response.ClearContent()
  25.         End If
  26.     End Sub
  27. End Class

A questo punto se la classe è nel web site in cui dobbiamo utilizzarla oppure si trova in un assembly in esso referenziato, il metodo start verrà eseguito allo start dell’applicazione e il modulo registrato.

Il tipo da eseguire all’avvio (il modulo nel nostro caso) deve essere pubblico e il metodo da eseguire Shared, altrimenti si ottiene una bella eccezione.

Altro vincolo è dato dal fatto che l’attributo PreApplicationStartMethodAttribute ha la seguente definizione:

  1. <AttributeUsageAttribute(AttributeTargets.Assembly, AllowMultiple := False)> _
  2. Public NotInheritable Class PreApplicationStartMethodAttribute _
  3.     Inherits Attribute

Come possiamo osservare si ha AllowMultiple=false il che significa che possiamo inserire un solo attributo per assembly.

Se abbiamo la necessità di gestire più oggetti di avvio, possiamo creare una classe di bootstrap formata dal solo metodo start al cui interno eseguiamo tutto ciò che dobbiamo fare:

  1. <Assembly: PreApplicationStartMethod(GetType(Bootstrapper), "Start")>
  2.  
  3. Public NotInheritable Class Bootstrapper
  4.     Public Shared Sub Start()
  5.         DynamicModuleUtility.RegisterModule(GetType(ProtectionModule))
  6.         ' altre attivit? da svolgere
  7.     End Sub
  8. End Class

 

Commenti

Post popolari in questo blog

VB.NET : Aggregare stringhe con LINQ

Tip facile facile, ma a qualcuno potrebbe servire. Supponiamo di avere una lista di stringhe (magari come risultato di una query LINQ) e di voler ottenere una stringa con la concatenazione delle stesse: Dim list = CreateList() Dim concatStr = (From s In list _ Select s).Aggregate( Function (currentString, nextString) currentString + nextString) MessageBox.Show(concatStr) Il metodo CreateList non ci interessa, in questo momento, ma crea una lista di oggetti String. Protected Function CreateList() As IEnumerable( Of String ) Dim list As String () = {" stringa1 ", " stringa2 ", " stringa3 ", " stringa4 ", " stringa5 "} Return list.AsEnumerable() End Function Questo metodo potrebbe restituire una qualsiasi lista di oggetti di cui, nella select successiva recuperiamo solo stringhe. La stessa tecnica è utilizzabile per concatenare stringhe inserendovi un carattere separatore Dim list = CreateList() Dim

VB.NET: SplashScreen con effetto fade-in

In questo post vorrei proporvi un modo per realizzare una splash screen per le nostre applicazioni Windows Form che appare progressivamente con un effetto fade. Supponiamo di avere il nostro progetto VB.NET in una soluzione Visual Studio 2008 in cui abbiamo il sorgente della nostra applicazione Windows Form. Inseriamo una splash screen utilizzando il menù Progetto->Aggiungi Nuovo Elemento e selezionando il tipo di elemento “Schermata Iniziale” A questo punto Visual Studio creerà, automaticamente, la schermata iniziale che possiamo personalizzare graficamente come vogliamo. Per poter fare in modo che questa finestra appaia nel momento in cui avviamo l’applicazione, è necessario aprire le proprietà del progetto e impostare la maschera di avvio: In questo modo, all’avvio dell’applicazione, la schermata appare immediatamente e scompare un attimo prima della visualizzazione della finestra dell’applicazione. Possiamo far apparire la schermata iniziale con un ef

VB.NET: Convertire un file DOC in RTF e PDF con office interop

In questo post vorrei proporvi del codice per poter convertire un file .doc in un file .rtf oppure .pdf utilizzando le API di interoperabilità di Office. Creeremo una classe, DocConverter, che esporrà le due funzionalità sopra citate. Cominciamo con il prevedere un attributo privato della classe che rappresenterà l’applicazione Word che utilizzeremo per la conversione. Creeremo l’istanza dell’attributo privato all’interno del costruttore della classe: Public Sub New () If Not CreateWordApp() Then Throw New ApplicationException(" Assembly di interoperabilità con Office non trovato! ") End If End Sub Private _wordApp As Word.ApplicationClass Protected Function CreateWordApp() As Boolean Dim retval = True Try _wordApp = New Word.ApplicationClass() _wordApp.Visible = False Catch ex As System.Exception _wordApp = Nothing retval = False End Try Return retval End Function La conve